芝麻web文件管理V1.00

编辑当前文件:/home/freeclou/resource.optimyar.com/Gams/MDCVRP.gms

*********** Homogeneous VRP   (withput defining set of vehicle)*****************
*********** Multiple Depots
********************************************************************************

** Author:  Ali Papi (papimath@hotmail.com)

**Telegram Group: https://t.me/joinchat/BUMSRz7BQKYWANk_vz5k2Q

Set
Node /depot1*depot10 , City1*City100/
Depot(Node) /depot1*depot10/
City(Node)/City1*City100/
;
Alias(Node,i,j)
;

Parameter c(i,j);
c(i,j)$(ord(j)>ord(i))=uniform(10,1000);
c(i,j)$(ord(j)<ord(i))=c(j,i);
Display c;

Binary Variable
x(i,j)
;
x.fx(depot,depot)=0;
Free Variable
Cost
;
Positive Variable
u(i)
;
u.fx(Depot)=0;

Equation
obj
Eq1
Eq2
Eq3
Eq4
;

obj..    cost =e= sum({i,j},c(i,j)*x(i,j));

Eq1(city)..         sum({i},x(i,city)) =e= 1;
Eq2(city)..         sum({i},x(city,i)) =e= 1;

Eq3(depot)..        sum({i},x(i,depot)) =e= sum({i},x(depot,i));

Eq4(i,j)$(city(j))..     u(j) =g= u(i) + x(i,j) - card(City)*(1-x(i,j));

Model VRP
/
obj
Eq1
Eq2
Eq3
Eq4
/

Options
MIP=CPLEX
RESLIM=100
OPTCR=0
;

Scalar ST,RT;

ST=Jnow;

Solve VRP us MIP min Cost;

*runtime second
RT=(Jnow-ST)*3600*24;

*Number of vehicles traveling from each depot
parameter NVD(depot);
NVD(depot)=sum({j},x.l(depot,j));

*Number of vehicles
parameter NV;
NV=sum({depot},NVD(depot));

Display
NVD
NV
x.l
u.l
cost.l
"Run Time"
RT

** Author:  Ali Papi (papimath@hotmail.com)
******************************************